Özel kabul addonu
#ozelkabul off
alias ozelkabul {
set %ozelkabul.nick $1
set %ozelkabul.address $2
set %ozelkabul.msg $3-
if ($dialog($1) != $null) { goto son }
dialog -m $1 ozelkabul
:son
}
dialog ozelkabul {
title "Özel Konuşma ısteği"
size -1 -1 164 61
option dbu
edit "", 1, 40 4 120 10, read
text "Nick :", 2, 4 7 27 8
text "Adres :", 3, 4 19 28 8
text "Mesaj :", 4, 4 31 28 8
edit "", 5, 40 18 121 10, read
edit "", 6, 40 30 121 10, read
button "Kabul ET", 7, 13 44 67 12, flat ok
button "Red ET", 8, 86 44 66 12, flat cancel
}
on *:dialog:*:init:*:{
if (Özel Konuşma ısteği == $dialog($dname).title ) {
set %ozelkabul.dialog $dname
did -a $dname 1 %ozelkabul.nick
did -a $dname 5 %ozelkabul.address
did -a $dname 6 %ozelkabul.msg
}
}
on *:dialog:*:sclick:*:{
if (Özel Konuşma ısteği == $dialog($dname).title ) {
if ($did == 7) {
.window -w $dname
.msg $dname Özel Konuşma ısteğiniz Kabul Edilmiştir.
.set %ozelkabul.gorusme. [ $+ [ $dname ] ] ok
}
if ($did == 8) {
.msg $dname Özel Konuşma ısteğiniz ReddediLdi .!
.ignore -pu300 $dname
.closemsg $dname
}
}
}
on *:TEXT:*:?:{
if ($nick == $me) { goto son }
if (%ozelkabul.gorusme. [ $+ [ $nick ] ] == $null) {
.ozelkabul $nick $address($nick,2) $1-
.msg $nick Mesajınız Başarıyla iletilmiştir, Lütfen Cevap Vermem için Bekleyiniz.
}
}
on *:CLOSE:?:{
if (%ozelkabul.gorusme. [ $+ [ $target ] ] != $null) { unset %ozelkabul.gorusme. [ $+ [ $target ] ] }
}
#ozelkabul end
menu channel,status,menubar,query {
Özel Kabul Sistemi
.Aç : .enable #ozelkabul
.Kapat: .disable #ozelkabul
}